home *** CD-ROM | disk | FTP | other *** search
/ Developer CD Series 1990: Discy Business / Discy Business.2mg / DEV.CD / GUIDED.TOURS / IIC.PLUS.TOUR / MENU / STARTUP (.txt) next >
Encoding:
Applesoft BASIC Source Code  |  1988-04-16  |  4.5 KB  |  144 lines  |  [FC] Applesoft BASIC Program (0x0801)
  1. 0  ONERR  GOTO 1000
  2. 1  PRINT  CHR$(21): POKE 49166,0: GOSUB 521: TEXT : HOME : POKE  -16298,0: POKE  -16300,0: POKE  -16368,0: POKE 34,0: POKE 33,40: GOSUB 3000
  3. 2  GOSUB 2100: GOSUB 311: FOR U = 1 TO 40: PRINT "_";: NEXT 
  4. 3  POKE  -16258,1: POKE  -16289,1: POKE  -16257,1
  5. 5  PRINT : PRINT "  1.  Apple Presents Apple"
  6. 6  IF PL = 0  THEN 8
  7. 7  PRINT : PRINT "  2.  Learning the Apple IIc Plus"
  8. 8  PRINT : PRINT "  ";PL +2;".  The Inside Story"
  9. 9  PRINT : PRINT "  ";PL +3;".  Getting Down to BASIC"
  10. 10  PRINT : PRINT "  ";PL +4;".  Apple at Work"
  11. 11  PRINT : PRINT "  ";PL +5;".  Apple at Play"
  12. 12  PRINT : PRINT "  ";PL +6;".  Quit"
  13. 13 T = 0: FOR I = 1 TO 6 +PL: IF  PEEK(I +839) = 1  THEN  HTAB (1): VTAB 2 +(2 *I): PRINT " "
  14. 21  IF  PEEK(I +839) = 1  THEN J = I +1:T = 1
  15. 22 T = 0
  16. 31  NEXT I: IF T < >1  THEN J = 1
  17. 40  GOSUB 321: VTAB 17: PRINT : PRINT "If this is the first time you've used   this disk, press RETURN.  Or, type a "
  18. 41  PRINT "number, or select with the UP or DOWN": PRINT "ARROW key. Then press RETURN.": FOR U = 1 TO 40: PRINT "_";: NEXT U
  19. 45  VTAB 24: PRINT "Copyright 1980-88 Apple Computer, Inc.";
  20. 51  VTAB 21: HTAB 35: CALL  -868: GET CH$: IF  ASC(CH$) = 27  THEN  GOTO 51
  21. 61  IF  ASC(CH$) = 13  THEN  GOTO 221
  22. 71  IF  ASC(CH$) < >10  AND  ASC(CH$) < >11  THEN 131
  23. 81  IF  ASC(CH$) = 10  THEN K = J:J = J +1
  24. 91  IF  ASC(CH$) = 11  THEN K = J:J = J -1
  25. 101  IF J = 7 +PL  THEN J = 1
  26. 111  IF J = 0  THEN J = 6 +PL
  27. 121  GOSUB 421: GOSUB 321: GOTO 51
  28. 131  IF  ASC(CH$) = 81  OR  ASC(CH$) = 113  THEN K = J:J = 6 +PL: GOTO 121
  29. 141  IF  ASC(CH$) <49  OR  ASC(CH$) >54 +PL  THEN 51
  30. 151  VTAB 21: HTAB 35: PRINT CH$:K = J:J =  ASC(CH$) -48: GOSUB 421: GOSUB 321
  31. 161  VTAB 21: HTAB 36: GET RE$: IF  ASC(RE$) = 13  THEN 221
  32. 171  IF  ASC(RE$) = 8  THEN 51
  33. 181  IF  ASC(RE$) = 10  THEN K = J:J = J +1: GOTO 101
  34. 191  IF  ASC(RE$) = 11  THEN K = J:J = J -1: GOTO 101
  35. 201  IF  ASC(RE$) <49  OR  ASC(RE$) >54 +PL  THEN 161
  36. 211 CH$ = RE$: GOTO 151
  37. 221  IF PL = 1  THEN 223
  38. 222  HOME : VTAB 10: HTAB 13: PRINT "Please wait...": ON J GOTO 231,241,251,261,271,281
  39. 223  HOME : VTAB 10: HTAB 13: PRINT "Please wait...": ON J GOTO 231,224,241,251,261,271,281
  40. 224  PRINT : PRINT  CHR$(4);"PREFIX /TUTOR/LEARNING": POKE 16384,0: POKE 104,64: POKE 103,1: HGR : TEXT : PRINT  CHR$(4);"PR #3"
  41. 225  FOR I = 0 TO 9: PRINT : NEXT : HTAB 30: PRINT "One moment please...": PRINT  CHR$(4);"RUN CDEMO"
  42. 231  PRINT : PRINT  CHR$(4);"PREFIX /TUTOR/PRESENTING"
  43. 232  PRINT  CHR$(4);"-APA"
  44. 241  PRINT : PRINT  CHR$(4);"PREFIX /TUTOR/INSIDE.STORY"
  45. 242  PRINT  CHR$(4);"-STARTUP"
  46. 251  GOTO 1100
  47. 252  PRINT : PRINT  CHR$(4);"PREFIX /TUTOR/BASIC"
  48. 253  PRINT  CHR$(4);"-STARTUP"
  49. 261  PRINT : PRINT  CHR$(4);"PREFIX /TUTOR/AT.WORK"
  50. 262  PRINT  CHR$(4);"-WORKING"
  51. 271  PRINT : PRINT  CHR$(4);"PREFIX /TUTOR/APPLE.PLAY"
  52. 272  PRINT  CHR$(4);"-STARTUP"
  53. 281  TEXT : HOME : VTAB 10: PRINT "Do you really want to quit?"
  54. 283  PRINT : PRINT "Press the 'Y' key if you really want"
  55. 285  PRINT "to quit, or any other key to return"
  56. 287  PRINT "to the main menu."
  57. 289  VTAB 10: HTAB 29: GET A$: PRINT A$
  58. 291  IF A$ = "Y"  OR A$ = "y"  THEN  PRINT  CHR$(4)"BYE"
  59. 292  RUN 
  60. 311 H = (40 - LEN(T$))/2 +1: HTAB H: PRINT T$: RETURN 
  61. 321  IF PL = 1  THEN 323
  62. 322  ON J GOSUB 341,351,361,371,381,391,401,411: GOTO 331
  63. 323  ON J GOSUB 341,336,351,361,371,381,391,401,411
  64. 331  VTAB 2 +(J *2): HTAB 6: PRINT T$;
  65. 336 T$ = "<LEARNING THE APPLE IIc PLUS>": RETURN 
  66. 341 T$ = "<APPLE PRESENTS APPLE>": RETURN 
  67. 351 T$ = "<THE INSIDE STORY>": RETURN 
  68. 361 T$ = "<GETTING DOWN TO BASIC>": RETURN 
  69. 371 T$ = "<APPLE AT WORK>": RETURN 
  70. 381 T$ = "<APPLE AT PLAY>": RETURN 
  71. 391 T$ = "<QUIT>": RETURN 
  72. 421  IF PL = 1  THEN 423
  73. 422  ON K GOSUB 441,451,461,471,481,491: GOTO 431
  74. 423  ON K GOSUB 441,436,451,461,471,481,491
  75. 431  VTAB 2 +(K *2): HTAB 6: PRINT T$;
  76. 436 T$ = " Learning the Apple IIc Plus ": RETURN 
  77. 441 T$ = " Apple Presents Apple ": RETURN 
  78. 451 T$ = " The Inside Story ": RETURN 
  79. 461 T$ = " Getting Down to BASIC ": RETURN 
  80. 471 T$ = " Apple at Work ": RETURN 
  81. 481 T$ = " Apple at Play ": RETURN 
  82. 491 T$ = " Quit ": RETURN 
  83. 521  FOR I = 768 TO 835: READ A: POKE I,A: NEXT I: DATA  173,50,190,72,173,51,190,72,169,30,141, 50,190,169,3,141,51,190,32,111,253,104, 141,51,190,104,141,50,190,96,32,27,253, 201,155,208,7,141,0,2,169,141,162,1,96, 162,0,32,117,253,160,2,138,145,105,200
  84. 531  DATA   169,0,145,105,200,169,2,145,105,76,57,213
  85. 541  FOR I = 850 TO 855: POKE I,0: NEXT I: RETURN 
  86. 1000 ERR% =  PEEK(222): IF ERR% = 255  THEN  RESUME 
  87. 1010  HOME : PRINT  CHR$(7);
  88. 1020  PRINT "Error #";ERR%;" has occurred. Please"
  89. 1025  PRINT "check that the proper disk is
  90. 1030  PRINT "in the drive and press RETURN"
  91. 1035  PRINT "to continue.";
  92. 1040  IF  PEEK(49152) < >141  THEN 1040
  93. 1050  POKE (49168),0
  94. 1055  RESTORE 
  95. 1060  RUN 
  96. 1100  REM  ---- basic check -----
  97. 1110  HOME 
  98. 1120  VTAB (4)
  99. 1130  PRINT "    Is your tour disk writable?"
  100. 1135  PRINT 
  101. 1140  PRINT "    If you are not sure, press the"
  102. 1150  PRINT "    disk eject button and check to"
  103. 1160  PRINT "    see that the small, square hole"
  104. 1165  PRINT "    on the top right side of the disk"
  105. 1170  PRINT "    is closed.  If you can see through"
  106. 1175  PRINT "    the hole, turn the disk over and"
  107. 1180  PRINT "    slide the small plastic square to"
  108. 1185  PRINT "    cover the hole.  Then return the"
  109. 1190  PRINT "    disk to the drive."
  110. 1195  PRINT : PRINT : PRINT 
  111. 1200  PRINT "    Press RETURN when you are sure"
  112. 1210  PRINT "    you can write on the tour disk or"
  113. 1220  PRINT "    press the ESC key if you want to"
  114. 1230  PRINT "    go back to the main menu."
  115. 1250  HTAB 20: GET C$
  116. 1260  IF  ASC(C$) = 13  THEN  HOME : VTAB 10: HTAB 12: PRINT "Please wait...": GOTO 2500
  117. 1270  IF  ASC(C$) = 27  THEN  RESTORE : GOTO 1
  118. 1280  GOTO 1250
  119. 2000  REM  ----- Check Machine Type --------
  120. 2100 PL = 0: IF  PEEK(64435) = 6  AND  PEEK(64448) = 0  AND  PEEK(64447) = 5  THEN PL = 1
  121. 2110 T$ = "Your Tour of the Apple II"
  122. 2120  IF PL = 1  THEN T$ = T$ +"c Plus"
  123. 2125  REM IF PL= 0 THEN T$ = "   " + T$
  124. 2130  RETURN 
  125. 2500  ONERR  GOTO 2900
  126. 2510  PRINT  CHR$(4);"OPEN WRITE.TST"
  127. 2520  PRINT  CHR$(4);"WRITE WRITE.TST"
  128. 2530  PRINT "This is a test"
  129. 2540  PRINT  CHR$(4);"CLOSE WRITE.TST"
  130. 2550  ONERR  GOTO 1000
  131. 2560  GOTO 252
  132. 2900  HOME : PRINT  CHR$(7);"    The disk is still write protected."
  133. 2905  PRINT  CHR$(4);"CLOSE"
  134. 2910  GOTO 1120
  135. 3000 KK = 1024 +123: HOME 
  136. 3010  POKE KK,0:KK = KK +128
  137. 3020  POKE KK,255:KK = KK +128
  138. 3030  POKE KK,000:KK = KK +128
  139. 3040  POKE KK,001:KK = KK +128
  140. 3050  POKE KK,247:KK = KK +128
  141. 3060  POKE KK,160:KK = KK +128
  142. 3062  POKE KK,160:KK = KK +128
  143. 3070  POKE KK,255:KK = KK +128
  144. 3090  HOME : RETURN